Synapas http Download from internet using threads in Free Pascal

In our previous example we have used Synapse  ThttpSend to download files from the web using blocking mode.

Now we want to unfreeze this blocking of application while downloading large files. We have used threads in this example. Before using thread we need to enable it first if we are using Linux.

By default we will find this compiler directive in main project source code:

uses
  {$IFDEF UNIX}{$IFDEF UseCThreads}
  cthreads,
  {$ENDIF}{$ENDIF}

Remove useCThreads part to be like this:

uses
  {$IFDEF UNIX}
  cthreads,
  {$ENDIF}

This is the form:

And this is the code of form unit:

unit main;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, process, FileUtil, Forms, Controls, Graphics, Dialogs,
  StdCtrls, Buttons, httpSend;

type

  { THTTPDownload }

  THTTPDownload = class(TThread)
    private
      fURL: string;
      fFileName: string;
    public
      constructor Create(URL, FileName: string);
      procedure Execute; override;
  end;

  { TfmMain }

  TfmMain = class(TForm)
    btDownload: TBitBtn;
    btGet: TButton;
    edURL: TEdit;
    Label1: TLabel;
    Memo1: TMemo;
    SaveDialog1: TSaveDialog;
    procedure btDownloadClick(Sender: TObject);
    procedure btGetClick(Sender: TObject);
  private
    procedure DownloadTerminiated(Sender: TObject);
    { private declarations }
  public
    { public declarations }
  end;

var
  fmMain: TfmMain;

implementation

{ THTTPDownload }

constructor THTTPDownload.Create(URL, FileName: string);
begin
  inherited Create(True);
  fURL:= URL;
  fFileName:= FileName;
end;

procedure THTTPDownload.Execute;
var
  httpClient: THTTPSend;
begin
  httpClient:= THTTPSend.Create;
  if httpClient.HTTPMethod('GET', fURL) then
    httpClient.Document.SaveToFile(fFileName);
      fmMain.Memo1.Lines.Add(fFileName + ', has been downloaded');

  httpClient.Free;
end;

{$R *.lfm}

{ TfmMain }

procedure TfmMain.btGetClick(Sender: TObject);
var
  httpClient: THTTPSend;
begin
  httpClient:= THTTPSend.Create;
  if httpClient.HTTPMethod('GET', edURL.Text) then
  begin
    Memo1.Lines.LoadFromStream(httpClient.Document);
  end;
  httpClient.Free;
end;

procedure TfmMain.DownloadTerminiated(Sender: TObject);
begin
  Memo1.Lines.Add('Thread finished');
  btDownload.Enabled:= True;
end;

procedure TfmMain.btDownloadClick(Sender: TObject);
var
  httpClient: THTTPSend;
  download: THTTPDownload;
begin
  SaveDialog1.FileName:= ExtractFileName(edURL.Text);
  if SaveDialog1.Execute then
  begin
    btDownload.Enabled:= False;
    download:= THTTPDownload.Create(edURL.Text, SaveDialog1.FileName);
    download.OnTerminate:= @DownloadTerminiated;
    download.Resume;
    memo1.Lines.Add('Download started');
  end;

end;

end.